archetype (adl_version=1.4)
	openEHR-EHR-EVALUATION.exclusion-family_history.v1
specialise
	openEHR-EHR-EVALUATION.exclusion.v1

concept
	[at0000.1]	-- Exclusion statement - Family History
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"heather.leslie@oceaninformatics.com">
		["date"] = <"2/03/2010">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To positively record the absence or exclusion of any problems or diagnoses in related family member within the health record.">
			use = <"Use to record the positive exclusion or absence of problems or diagnoses in related family members within the health record. This archetype avoids the need to use terminology to express negation for any problem or diagnosis within the health record or that it is not about the patient themselves.
This archetype is only to be used to record 'point in time' information. It is not to be used for a persistent storage of information as the patient should always be questioned about the occurrence of problems or diagnoses in family members during history taking and prior to initiation of any treatment or management plan.">
			keywords = <"exclusion", "no", "nil", "significant", "relevant", "family", "diagnosis", "problem">
			misuse = <"">
			copyright = <"copyright (c) 2010 openEHR foundation">
		>
	>
	lifecycle_state = <"0">
	other_contributors = <"Sam Heard, Ocean Informatics, Australia", ...>
	other_details = <
		["MD5-CAM-1.0.1"] = <"E6E61B592A182489F992E240D30EA346">
		["references"] = <"">
	>

definition
	EVALUATION[at0000.1] matches {	-- Exclusion statement - Family History
		data matches {
			ITEM_TREE[at0001] matches {	-- Tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0002] occurrences matches {0..*} matches {	-- General Statement
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0.3] occurrences matches {0..*} matches {	-- Global Statement
						value matches {
							DV_CODED_TEXT matches {
								defining_code matches {
									[local::
									at0.4, 	-- No significant family history 
									at0.5]	-- No relevant family history
								}
							}
						}
					}
					ELEMENT[at0.6] occurrences matches {0..1} matches {	-- No significant family history of
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0.7] occurrences matches {0..1} matches {	-- No relevant family history of
						value matches {
							DV_TEXT matches {*}
						}
					}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0.3"] = <
					text = <"Global Statement">
					description = <"Global statements about the exclusion. This can be used to capture any information that is needed to be explicitly recorded as being absent or excluded within the record.">
				>
				["at0.4"] = <
					text = <"No significant family history ">
					description = <"No significant family history of any problem or diagnosis.">
				>
				["at0.5"] = <
					text = <"No relevant family history">
					description = <"No relevant family history of any problem or diagnosis.">
				>
				["at0.6"] = <
					text = <"No significant family history of">
					description = <"Positive statement about significant problems and diagnoses in related family members that are explicitly known to have not been identified at the time of recording.">
				>
				["at0.7"] = <
					text = <"No relevant family history of">
					description = <"Positive statement about relevant problems and diagnoses in related family members that are explicitly known to have not been identified at the time of recording.">
				>
				["at0000"] = <
					text = <"Exclusion statement">
					description = <"Statements that need to be positively recorded as absent or excluded.">
				>
				["at0000.1"] = <
					text = <"Exclusion statement - Family History">
					description = <"Statements about Family History that need to be positively recorded as absent or excluded.">
				>
				["at0001"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"General Statement">
					description = <"The statement about the absence or exclusion. Use to capture any information that is needed to be explicitly recorded as being absent or excluded within the record.">
				>
			>
		>
	>