archetype (adl_version=1.4)
	openEHR-DEMOGRAPHIC-ROLE.healthcare_provider_organisation.v1

concept
	[at0000]	-- Prestador de assistência à saúde
language
	original_language = <[ISO_639-1::pt-br]>
	translations = <
		["en"] = <
			language = <[ISO_639-1::en]>
			author = <
				["name"] = <"Sergio Miranda Freire">
				["organisation"] = <"Universidade do Estado do Rio de Janeiro - UERJ">
				["email"] = <"sergio@lampada.uerj.br">
			>
		>
	>
description
	original_author = <
		["name"] = <"Sergio Miranda Freire & Rigoleta Dutra Mediano Dias">
		["organisation"] = <"Universidade do Estado do Rio de Janeiro - UERJ">
		["email"] = <"sergio@lampada.uerj.br">
		["date"] = <"22/05/2009">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"Representation of an organisations's demographic data in the role of healthcare provider">
			use = <"Used in demographic service to collect demographic data about an organisation in the role of a healthcare provider">
			keywords = <"demographic service", "healthcare provider organisation">
			misuse = <"">
			copyright = <"copyright (c) 2009 openEHR Foundation">
		>
		["pt-br"] = <
			language = <[ISO_639-1::pt-br]>
			purpose = <"Representação dos dados de uma Organização ao exercer o papel de um prestador de assistência à saúde">
			use = <"Usado em serviços de demografia para coletar dados demográficos sobre uma organização no papel de prestador de assistência à saúde">
			keywords = <"serviço demográfico", "organização prestadora de assistência à saúde">
			misuse = <"">
			copyright = <"copyright (c) 2009 openEHR Foundation">
		>
	>
	lifecycle_state = <"Authordraft">
	other_contributors = <>

definition
    ROLE[at0000] matches {   
        details matches {
            ITEM_TREE[at0001] occurrences matches {0..1} matches {  -- Identifiers
                items existence matches {0..1} cardinality matches {1..*; unordered; unique} matches {
                    allow_archetype CLUSTER[at0010] occurrences matches {1..*} matches {
                        include
                            archetype_id/value matches {/(provider_identifier)[a-zA-Z0-9_-]*\.v1/}
                    }
                }
            }
        }
        identities cardinality matches {1..*; ordered} matches {
            allow_archetype PARTY_IDENTITY[at0002] occurrences matches {1..*} matches {
                include
                    archetype_id/value matches {/(organisation_name)[a-zA-Z0-9_-]*\.v1/}
            }
        }
        relationships cardinality matches {0..*; ordered} matches {
            PARTY_RELATIONSHIP[at0003] occurrences matches {1..1} matches {  -- Relationship with a third-party payer
                details matches {
                    ITEM_TREE[at0030] occurrences matches {0..1} matches {  
                        items cardinality matches {1..*; ordered} matches {
                            allow_archetype CLUSTER[at0031] occurrences matches {0..1} matches {
                                include
                                    archetype_id/value matches {/(provider_identifier)[a-zA-Z0-9_-]*\.v1/}
                            }
                        }
                    }
                }
            }
        }
    }

ontology
	term_definitions = <
		["pt-br"] = <
			items = <
				["at0000"] = <
					text = <"Prestador de assistência à saúde">
					description = <"Organização no papel de um prestador de assistência à saúde">
				>
				["at0001"] = <
					text = <"Identificadores">
					description = <"Identificadores utilizados pela organização quando atua como prestador de assistência à saúde">
				>
				["at0002"] = <
					text = <"Nome do prestador">
					description = <"Especifica como a organização prestadora de assistência à saúde é conhecida">
				>
				["at0003"] = <
					text = <"Relacionamento com fonte pagadora">
					description = <"Relacionamento entre a organização prestadora de assistência e uma fonte pagadora">
				>
				["at0010"] = <
					text = <"Identificador">
					description = <"Identificador utilizado pelo prestador de assistência à saúde">
				>
				["at0030"] = <
					text = <"Detalhes">
					description = <"Detalhes do relacionamento">
				>
				["at0031"] = <
					text = <"Identificador">
					description = <"Identificador utilizado pelo prestador no relacionamento com a fonte pagadora">
				>
			>
		>
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Healthcare Provider Organisation">
					description = <"Organisation in the role of a healthcare provider">
				>
				["at0001"] = <
					text = <"Identifiers">
					description = <"The identifiers used by the organisation acting as a healthcare provider organisation">
				>
				["at0002"] = <
					text = <"Provider name">
					description = <"Indicates how the healthcare provider organisation is known by">
				>
				["at0003"] = <
					text = <"Third-party payer relationship">
					description = <"relationship between the healthcare provider organisation and a third-party payer">
				>
				["at0010"] = <
					text = <"Identifier">
					description = <"The identifier used by the organisation in the role of a healthcare provider organisation">
				>
				["at0030"] = <
					text = <"Details">
					description = <"Relationship details">
				>
				["at0031"] = <
					text = <"identifier used in the relationship">
					description = <"Identifier used by the healthcare provider in the relationship with the third-party payer">
				>
			>
		>
	>