archetype (adl_version=1.4)
	openEHR-DEMOGRAPHIC-CLUSTER.person_other_death_data.v1

concept
	[at0000]	-- Dados adicionais do óbito
language
	original_language = <[ISO_639-1::pt-br]>
	translations = <
		["en"] = <
			language = <[ISO_639-1::en]>
			author = <
				["name"] = <"Sergio Miranda Freire">
				["organisation"] = <"Universidade do Estado do Rio de Janeiro - UERJ">
				["email"] = <"sergio@lampada.uerj.br">
			>
		>
	>
description
	original_author = <
		["name"] = <"Sergio Miranda Freire & Rigoleta Dutra Mediano Dias">
		["organisation"] = <"Universidade do Estado do Rio de Janeiro - UERJ">
		["email"] = <"sergio@lampada.uerj.br">
		["date"] = <"20/05/2009">
	>
	details = <
		["pt-br"] = <
			language = <[ISO_639-1::pt-br]>
			purpose = <"Coleta de dados demográficos sobre o óbito de um indivíduo">
			use = <"Usado em serviços de demografia para coletar dados relativos ao local e número do certificado de óbito de um indivíduo">
			keywords = <"serviço demográfico", "dados demográficos do óbito">
			misuse = <"">
			copyright = <"copyright (c) 2009 openEHR Foundation">
		>
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"Representation of a person's demographic death data">
			use = <"Used in demographic services to collect data about the place and death certificate number of a person's death">
			keywords = <"demographic service", "death demographic data">
			misuse = <"">
			copyright = <"copyright (c) 2009 openEHR Foundation">
		>
	>
	lifecycle_state = <"AuthorDraft">
	other_contributors = <>

definition
	CLUSTER[at0000] matches {	-- other death demographic data
		items cardinality matches {1..*; ordered} matches {	
			ELEMENT[at0001] occurrences matches {0..1} matches {	-- country of death
				value matches {
					DV_CODED_TEXT matches {
						defining_code matches {[ac0000]}  -- country codes
					}
				}
			}
			ELEMENT[at0002] occurrences matches {0..1} matches {	-- state/territory/province
				value matches {
					DV_CODED_TEXT matches {
						defining_code matches {[ac0001]}  -- state codes
					}
				}
			}
			ELEMENT[at0003] occurrences matches {0..1} matches {	-- city/town/locality
				value matches {
					DV_CODED_TEXT matches {
						defining_code matches {[ac0002]}    -- city codes
					}
				}
			}
			ELEMENT[at0004] occurrences matches {0..1} matches {	-- certificate number
				value matches {
					DV_TEXT matches {*}
				}
			}
		}
	}

ontology
	term_definitions = <
		["pt-br"] = <
			items = <
				["at0000"] = <
					text = <"Dados adicionais do óbito">
					description = <"Dados demográficos adicionais do óbito">
				>
				["at0001"] = <
					text = <"País">
					description = <"O país onde a pessoa faleceu">
				>
				["at0002"] = <
					text = <"Estado/território/província">
					description = <"O estado/território/província onde a pessoa faleceu">
				>
				["at0003"] = <
					text = <"Cidade/localidade">
					description = <"A cidade/localidade onde a pessoa faleceu">
				>
				["at0004"] = <
					text = <"Número do certificado">
					description = <"Informa o número do certificado de óbito">
				>
			>
		>
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Death additional data">
					description = <"Death additional demographic data">
				>
				["at0001"] = <
					text = <"Country">
					description = <"The country where a person  died">
				>
				["at0002"] = <
					text = <"State/territory/province">
					description = <"The state/territory/province where a person died">
				>
				["at0003"] = <
					text = <"City/town/locality">
					description = <"The city/town/locality where a person died">
				>
				["at0004"] = <
					text = <"Death certificate number">
					description = <"The number of the death certificate">
				>
			>
		>
	>
	constraint_definitions = <
		["pt-br"] = <
			items = <
				["ac0000"] = <
					text = <"Códigos de países">
					description = <"códigos válidos para paises">
				>
				["ac0001"] = <
					text = <"Códigos de estados">
					description = <"códigos válidos para estados">
				>
				["ac0002"] = <
					text = <"Códigos de cidades">
					description = <"códigos válidos para cidade">
				>
			>
		>
		["en"] = <
			items = <
				["ac0000"] = <
					text = <"Country codes">
					description = <"valid codes for countries">
				>
				["ac0001"] = <
					text = <"State codes">
					description = <"valid codes for state/territory/province">
				>
				["ac0002"] = <
					text = <"City codes">
					description = <"valid codes for city/town/locality">
				>
			>
		>
	>