archetype (adl_version=1.4)
	openEHR-EHR-CLUSTER.telecom_details.v1

concept
	[at0000]	-- Telecom details
language
	original_language = <[ISO_639-1::en]>
	translations = <
		["de"] = <
			language = <[ISO_639-1::de]>
			author = <
				["name"] = <"Hans Demski">
				["organisation"] = <"Helmholtz Zentrum München">
				["email"] = <"demski@helmholtz-muenchen.de">
			>
		>
	>
description
	original_author = <
		["name"] = <"Ian McNicoll">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"ian.mcnicoll@oceaninformatics.com">
		["date"] = <"14/11/2007">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record telecommunications details for an individual or organisation.">
			use = <"Use to record telecommunications details for an individual or organisation, including email or other internet based communication.">
			keywords = <"telephone", "facsimile", "fax", "mobile", "email", "pager">
			misuse = <"">
			copyright = <"copyright (c) 2010 openEHR foundation">
		>
		["de"] = <
			language = <[ISO_639-1::de]>
			purpose = <"Zur Dokumentation von Kontaktdaten einer Person oder Einrichtung.">
			use = <"Zur Dokumentation von Kontaktdaten einer Person oder Einrichtung, einschließlich Email oder weiterer internetbasierter Kommunikationsmittel.">
			keywords = <"Telefon", "Mobilfunk", "Email", "Pager", "Handy", "Telefax">
			misuse = <"">
			copyright = <"copyright (c) 2010 openEHR foundation">
		>
	>
	lifecycle_state = <"AuthorDraft">
	other_contributors = <"Heather Leslie, Ocean Informatics, Australia", ...>
	other_details = <
		["MD5-CAM-1.0.1"] = <"AF0EA194F488E78D3E7D5A7CB09EA243">
		["references"] = <"Telephone, facsimile or similar telecommunications type/number for a patient.  ENV 13606 - 4:2000 7.11.14 From NHS Scotland SCI-XML messaging standards http://www.isdscotland.org/isd/files/general-v2-7.xsd NHS Scotland Interoperability Working Group http://www.isdscotland.org/isd/5194.html.">
	>

definition
	CLUSTER[at0000] matches {	-- Telecom details
		items cardinality matches {1..*; unordered} matches {
			ELEMENT[at0010] occurrences matches {0..*} matches {	-- Mode
				value matches {
					DV_CODED_TEXT matches {
						defining_code matches {
							[local::
							at0011, 	-- Home
							at0012, 	-- Work
							at0018]	-- Contact
						}
					}
				}
			}
			CLUSTER[at0001] occurrences matches {0..*} matches {	-- Telecoms
				items cardinality matches {1..*; unordered} matches {
					ELEMENT[at0004] matches {	-- Telecoms type
						value matches {
							DV_CODED_TEXT matches {
								defining_code matches {
									[local::
									at0013, 	-- Telephone
									at0014, 	-- Fax
									at0015, 	-- Mobile phone
									at0016]	-- Pager
								}
							}
						}
					}
					ELEMENT[at0002] occurrences matches {0..1} matches {	-- Unstuctured telecoms
						value matches {
							DV_TEXT matches {*}
						}
					}
					CLUSTER[at0003] occurrences matches {0..1} matches {	-- Structured telecoms
						items cardinality matches {1..*; unordered} matches {
							ELEMENT[at0005] occurrences matches {0..1} matches {	-- Country code
								value matches {
									DV_TEXT matches {*}
								}
							}
							ELEMENT[at0006] occurrences matches {0..1} matches {	-- Area code
								value matches {
									DV_TEXT matches {*}
								}
							}
							ELEMENT[at0007] occurrences matches {0..1} matches {	-- Number
								value matches {
									DV_TEXT matches {*}
								}
							}
							ELEMENT[at0019] occurrences matches {0..1} matches {	-- Extension
								value matches {
									DV_TEXT matches {*}
								}
							}
						}
					}
				}
			}
			ELEMENT[at0009] occurrences matches {0..*} matches {	-- Email address
				value matches {
					DV_TEXT matches {*}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Telecom details">
					description = <"Personal or organisational telephone, fax, and email details.">
				>
				["at0001"] = <
					text = <"Telecoms">
					description = <"One or more telecoms contacts for an individual.">
				>
				["at0002"] = <
					text = <"Unstuctured telecoms">
					description = <"An unstructured description of telecoms.">
				>
				["at0003"] = <
					text = <"Structured telecoms">
					description = <"A structure for telephone numbers composed of separately identifiable elements. ENV13606-4:2000 7.11.18.">
				>
				["at0004"] = <
					text = <"Telecoms type">
					description = <"Telecom mechanism e.g. telephone, facsimile, pager etc.  ENV 13606-4:2000 7.11.19.">
				>
				["at0005"] = <
					text = <"Country code">
					description = <"Telephone country code.  ENV13606-4:2000 7.11.18.">
				>
				["at0006"] = <
					text = <"Area code">
					description = <"Telephone area code.">
				>
				["at0007"] = <
					text = <"Number">
					description = <"Telephone number.">
				>
				["at0009"] = <
					text = <"Email address">
					description = <"Email address.">
				>
				["at0010"] = <
					text = <"Mode">
					description = <"A qualifier for a telecom contact, describing its context e.g. 'Work', 'Home'.   ENV 13606 - 4:2000 7.11.19.">
				>
				["at0011"] = <
					text = <"Home">
					description = <"Telecommunication detail for home.">
				>
				["at0012"] = <
					text = <"Work">
					description = <"Telecommunication detail for work.">
				>
				["at0013"] = <
					text = <"Telephone">
					description = <"Telephone number details.">
				>
				["at0014"] = <
					text = <"Fax">
					description = <"Facsimile number details.">
				>
				["at0015"] = <
					text = <"Mobile phone">
					description = <"Mobile phone number details.">
				>
				["at0016"] = <
					text = <"Pager">
					description = <"Pager number details.">
				>
				["at0018"] = <
					text = <"Contact">
					description = <"Contact.">
				>
				["at0019"] = <
					text = <"Extension">
					description = <"Telephone extension number.  ENV13606-4:2000 7.11.18.">
				>
			>
		>
		["de"] = <
			items = <
				["at0000"] = <
					text = <"Kontaktdaten">
					description = <"Angaben zur Kontaktaufnahme mit einer Person oder Einrichtung per Telefon, Faxgerät oder Email">
				>
				["at0001"] = <
					text = <"Kontaktdaten">
					description = <"Eine oder mehrere Kontaktadressen einer Person oder Einrichtung">
				>
				["at0002"] = <
					text = <"Unstrukturierte Kontaktadresse">
					description = <"Unstrukturierte Kontaktadresse">
				>
				["at0003"] = <
					text = <"Strukturierte Kontaktadresse">
					description = <"Strukturierte Angabe von Telefonnummern mit Feldern nach ENV13606-4:2000 7.11.18">
				>
				["at0004"] = <
					text = <"Kontakttyp">
					description = <"Typ des Kontakts z.B. Telefon, Fax, Pager etc.  ENV 13606-4:2000 7.11.19">
				>
				["at0005"] = <
					text = <"Landesvorwahl">
					description = <"Landesvorwahl.  ENV13606-4:2000 7.11.18">
				>
				["at0006"] = <
					text = <"Ortsnetzkennzahl">
					description = <"Ortsnetzkennzahl oder Vorwahlteil einer Sonderrufnummer">
				>
				["at0007"] = <
					text = <"Nummer">
					description = <"Telefonnummer">
				>
				["at0009"] = <
					text = <"Emailadresse">
					description = <"Emailadresse">
				>
				["at0010"] = <
					text = <"Art">
					description = <"Zuordnung einer Kontaktangabe bzgl. der Umgebung z.B. 'Arbeit', 'Privat'.   ENV 13606 - 4:2000 7.11.19(en)">
				>
				["at0011"] = <
					text = <"Privat">
					description = <"*">
				>
				["at0012"] = <
					text = <"Arbeit">
					description = <"*">
				>
				["at0013"] = <
					text = <"Telefon">
					description = <"*">
				>
				["at0014"] = <
					text = <"Telefax">
					description = <"*">
				>
				["at0015"] = <
					text = <"Mobiltelefon">
					description = <"*">
				>
				["at0016"] = <
					text = <"Pager">
					description = <"*">
				>
				["at0018"] = <
					text = <"Kontakt">
					description = <"*">
				>
				["at0019"] = <
					text = <"Durchwahl">
					description = <"Durchwahl. ENV13606-4:2000 7.11.18">
				>
			>
		>
	>