archetype (adl_version=1.4)
	openEHR-EHR-CLUSTER.exam-generic-joint.v1
specialise
	openEHR-EHR-CLUSTER.exam-generic.v1

concept
	[at0000.1.1]	-- Examination of a named joint
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Sam Heard">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"sam.heard@oceaninformatics.com">
		["date"] = <"23/04/2007">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"A generic cluster for recording findings on physical examination of a joint.

.">
			use = <"">
			keywords = <"examination", "physical", "joint">
			misuse = <"">
			copyright = <"copyright (c) 2010 openEHR Foundation">
		>
	>
	lifecycle_state = <"AuthorDraft">
	other_contributors = <>
	other_details = <
		["MD5-CAM-1.0.1"] = <"CD624D54E78341D7B6C6F4BDFA855072">
		["references"] = <"">
	>

definition
	CLUSTER[at0000.1.1] matches {	-- Examination of a named joint
		items cardinality matches {1..*; unordered} matches {
			ELEMENT[at0.9.1] matches {	-- Joint
				value matches {
					DV_TEXT matches {*}
				}
			}
			CLUSTER[at0004] occurrences matches {0..1} matches {	-- Normal statements
				items cardinality matches {1..*; unordered} matches {
					ELEMENT[at0005] occurrences matches {0..*} matches {	-- Normal statement
						value matches {
							DV_TEXT matches {*}
						}
					}
				}
			}
			ELEMENT[at0002] occurrences matches {0..1} matches {	-- Clinical description
				value matches {
					DV_TEXT matches {*}
				}
			}
			CLUSTER[at0008.0.1] occurrences matches {0..1} matches {	-- Joint findings
				items cardinality matches {1..*; unordered} matches {
					allow_archetype CLUSTER[at0.0.2] occurrences matches {0..*} matches {	-- Joint detail
						include
							archetype_id/value matches {/openEHR-EHR-CLUSTER\.inspection-joint(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.inspection(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.move-joint(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.move(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.palpation-joint(-[a-zA-Z0-9_]+)*\.v1/}
					}
					allow_archetype CLUSTER[at0.11] occurrences matches {0..1} matches {	-- Size
						include
							archetype_id/value matches {/openEHR-EHR-CLUSTER\.physical_properties(-[a-zA-Z0-9_]+)*\.v1/}
					}
					allow_archetype CLUSTER[at0009] occurrences matches {0..*} matches {	-- Detail
						include
							archetype_id/value matches {/openEHR-EHR-CLUSTER\.exam-generic(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.inspection(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.palpation(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.percussion(-[a-zA-Z0-9_]+)*\.v1/}
					}
				}
			}
			ELEMENT[at0006] occurrences matches {0..*} matches {	-- Image
				value matches {
					DV_MULTIMEDIA matches {
						media_type matches {
							[openEHR::
							426, 
							427, 
							429]
						}
					}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0.0.2"] = <
					text = <"Joint detail">
					description = <"Detail relating to the joint.">
				>
				["at0.11"] = <
					text = <"Size">
					description = <"Information about the size of the object for examination.">
				>
				["at0.9"] = <
					text = <"Object">
					description = <"The object of examination.">
				>
				["at0.9.1"] = <
					text = <"Joint">
					description = <"The joint examined.">
				>
				["at0000"] = <
					text = <"Examination">
					description = <"Generic examination cluster for describing a finding on physical examination.">
				>
				["at0000.1"] = <
					text = <"Examination of a named body part">
					description = <"Generic examination cluster for describing a finding on physical examination.">
				>
				["at0000.1.1"] = <
					text = <"Examination of a named joint">
					description = <"For describing a finding on physical examination of a named joint.">
				>
				["at0002"] = <
					text = <"Clinical description">
					description = <"Textural description of the part examined.">
				>
				["at0004"] = <
					text = <"Normal statements">
					description = <"A group of statements about the normality of the examination.">
				>
				["at0005"] = <
					text = <"Normal statement">
					description = <"A specific statement of normality.">
				>
				["at0006"] = <
					text = <"Image">
					description = <"Drawing or image of the area examined.">
				>
				["at0008"] = <
					text = <"Findings">
					description = <"Clinical findings.">
				>
				["at0008.0.1"] = <
					text = <"Joint findings">
					description = <"Clinical findings for a single joint.">
				>
				["at0009"] = <
					text = <"Detail">
					description = <"More focused examination findings.">
				>
			>
		>
	>