archetype (adl_version=1.4)
	openEHR-EHR-CLUSTER.individual_personal_uk.v1

concept
	[at0000]	-- Individual's personal demographics (UK)
language
	original_language = <[ISO_639-1::en]>
	translations = <
		["de"] = <
			language = <[ISO_639-1::de]>
			author = <
				["name"] = <"Hans Demski">
				["organisation"] = <"Helmholtz Zentrum München">
				["email"] = <"demski@helmholtz-muenchen.de">
			>
		>
	>
description
	original_author = <
		["name"] = <"Ian McNicoll">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"ian.mcnicoll@oceaninformatics.com">
		["date"] = <"12/11/2007">
	>
	details = <
		["de"] = <
			language = <[ISO_639-1::de]>
			purpose = <"Zur Dokumentation persönlicher Daten wie Name(n), Adresse(n) und Kontaktmöglichkeit(en) einer Person die nicht eindeutig Registern mit demografischen Daten zugeordnet werden kann.">
			use = <"Zur Dokumentation persönlicher Daten von Bezugspersonen (z.B. Familenmitgliedern) die nicht eindeutig Registern mit demografischen Daten (z.B. einer elektronischen Krankenakte) zugeordnet werden können. Um die mehrfache Erstellung von eingebetteten Clustern zu vermeiden wäre es gut Templates für spezielle Anwendungsfälle zu erstellen.">
			keywords = <"Person", "Persönliche Daten", "Name", "Adresse", "Kontakt">
			misuse = <"Nicht zur Identifikation von Individuen zu benutzen, die eindeutig Registern mit demografischen Daten zugeordnet werden können (z.B. einer elektronischen Krankenakte, einem Master Patient Index, etc.).">
			copyright = <"© openEHR Foundation">
		>
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record personal demographics including name(s), Address(es) or telecoms contacts for a person not uniquely identifiied within the electronic health record.">
			use = <"Use to record details of external parties e.g family members who cannot be referenced uniquely within the electronic health record. Would benefit from templating this for specific use-cases to avoid having to construct the nested clusters each time.">
			keywords = <"person", "demographics", "name", "address", "telecom">
			misuse = <"Not to be used to identify the individuals who can be uniquely referenced from registers of demographic details eg within the electronic health record, master patient indexes etc.">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"AuthorDraft">
	other_contributors = <"Heather Leslie, Ocean Informatics, Australia", ...>
	other_details = <
		["references"] = <"NHS Scotland SCI-XML messaging standards http://www.isdscotland.org/isd/files/general-v2-7.xsd NHS Scotland Interoperability Working Group http://www.isdscotland.org/isd/5194.html and based on a  structure for personal data pertaining to a person.  ENV 13606 - 4:2000 7.6.12-14

HSCIC Data Dictionary Person Class http://www.datadictionary.nhs.uk/data_dictionary/classes/p/person_re.asp?shownav=1">
		["MD5-CAM-1.0.1"] = <"1FBD3A0D0A53F016CEE38900DC482B1F">
	>

definition
	CLUSTER[at0000] matches {	-- Individual's personal demographics (UK)
		items cardinality matches {1..*; unordered} matches {
			allow_archetype CLUSTER[at0013] occurrences matches {0..1} matches {	-- Name
				include
					archetype_id/value matches {/openEHR-EHR-CLUSTER\.person_name\.v1/}
				exclude
					archetype_id/value matches {/.*/}
			}
			allow_archetype CLUSTER[at0014] occurrences matches {0..*} matches {	-- Address details
				include
					archetype_id/value matches {/.*/}
			}
			allow_archetype CLUSTER[at0015] occurrences matches {0..*} matches {	-- Telecom details
				include
					archetype_id/value matches {/.*/}
			}
			ELEMENT[at0008] occurrences matches {0..1} matches {	-- Relationship to subject
				value matches {
					DV_TEXT matches {*}
				}
			}
			ELEMENT[at0016] occurrences matches {0..1} matches {	-- Identifier
				value matches {
					DV_IDENTIFIER matches {*}
				}
			}
			ELEMENT[at0007] occurrences matches {0..1} matches {	-- Date of Birth
				value matches {
					DV_DATE_TIME matches {*}
				}
			}
			ELEMENT[at0017] occurrences matches {0..1} matches {	-- Gender
				value matches {
					DV_CODED_TEXT matches {
						defining_code matches {
							[local::
							at0020, 	-- Male
							at0021, 	-- Female
							at0023]	-- Not specified
						}
					}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Individual's personal demographics (UK)">
					description = <"Personal demographics including name(s) , addresse(s) and telecommunication contact details.">
				>
				["at0007"] = <
					text = <"Date of Birth">
					description = <"Individual's date of birth.">
				>
				["at0008"] = <
					text = <"Relationship to subject">
					description = <"The relationship of this individual to the subject e.g. family member, informal carer.">
				>
				["at0013"] = <
					text = <"Name">
					description = <"Name details of the individual.">
				>
				["at0014"] = <
					text = <"Address details">
					description = <"Address details of the individual.">
				>
				["at0015"] = <
					text = <"Telecom details">
					description = <"Telecommunication details of the individual.">
				>
				["at0016"] = <
					text = <"Identifier">
					description = <"Identifier of individual.">
				>
				["at0017"] = <
					text = <"Gender">
					description = <"The administrative phenotypical  gender of the individual.">
				>
				["at0020"] = <
					text = <"Male">
					description = <"The gender of the individual is male.">
				>
				["at0021"] = <
					text = <"Female">
					description = <"The gender of the individual is female.">
				>
				["at0023"] = <
					text = <"Not specified">
					description = <"The individual's gender is not specified or is indeterminate.">
				>
			>
		>
		["de"] = <
			items = <
				["at0000"] = <
					text = <"Persönliche Daten">
					description = <"Persönliche Daten wie Name(n), Adresse(n) und Kontaktmöglichkeit(en)">
				>
				["at0007"] = <
					text = <"Geburtsdatum">
					description = <"Geburtsdatum">
				>
				["at0008"] = <
					text = <"Art der Beziehung">
					description = <"Beschreibt die Art der Beziehung z.B. Familienmitglied,gesetzlicher Betreuer">
				>
				["at0013"] = <
					text = <"Name">
					description = <"*">
				>
				["at0014"] = <
					text = <"Adressangaben">
					description = <"*">
				>
				["at0015"] = <
					text = <"Kontaktdetails">
					description = <"*">
				>
				["at0016"] = <
					text = <"*New element(en)">
					description = <"**(en)">
				>
				["at0017"] = <
					text = <"*Gender(en)">
					description = <"*The administrative gender of the individual.(en)">
				>
				["at0020"] = <
					text = <"*Male(en)">
					description = <"**(en)">
				>
				["at0021"] = <
					text = <"*Female(en)">
					description = <"**(en)">
				>
				["at0023"] = <
					text = <"*Not specified(en)">
					description = <"*The person's gender is not specified or is indeterminate.(en)">
				>
			>
		>
	>