archetype (adl_version=1.4)
	openEHR-EHR-OBSERVATION.rinne_weber_result.v1

concept
	[at0000]	-- Rinne and Weber Test Results
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"heather.leslie@oceaninformatics.com">
		["date"] = <"2013-03-26">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record the results of the Rinne and Weber tests as part of screening for hearing loss.">
			use = <"Use to record the results of the Rinne and Weber tests as part of screening for hearing loss.">
			keywords = <"rinne", "weber", "test", "result", "air", "bone", "conduction", "lateralisation", "lateralization">
			misuse = <"Not to be used to record the results of other hearing tests. Use other OBSERVATION archetypes specific for the purpose, for example, OBSERVATION.audiometry_result and OBSERVATION.tympanogram_226hz.">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"CommitteeDraft">
	other_contributors = <"Ian McNicoll, Ocean Informatics, UK", ...>
	other_details = <
		["current_contact"] = <"Heather Leslie, Ocean Informatics, heather.leslie@oceaninformatics.com">
		["MD5-CAM-1.0.1"] = <"E4452413C8C5DA6FAD4CA3542E145C65">
	>

definition
	OBSERVATION[at0000] matches {	-- Rinne and Weber Test Results
		data matches {
			HISTORY[at0001] matches {	-- Event Series
				events cardinality matches {1..*; unordered} matches {
					EVENT[at0002] occurrences matches {0..1} matches {	-- Any event
						data matches {
							ITEM_TREE[at0003] matches {	-- Tree
								items cardinality matches {0..*; unordered} matches {
									ELEMENT[at0004] occurrences matches {0..1} matches {	-- Weber Test Result
										value matches {
											DV_CODED_TEXT matches {
												defining_code matches {
													[local::
													at0005, 	-- No Lateralisation
													at0006, 	-- Lateralising Left
													at0007]	-- Lateralising Right
												}
											}
										}
									}
									CLUSTER[at0008] occurrences matches {0..2} matches {	-- Rinne Test
										items cardinality matches {1..*; unordered} matches {
											ELEMENT[at0010] occurrences matches {0..1} matches {	-- Ear Tested
												value matches {
													DV_CODED_TEXT matches {
														defining_code matches {
															[local::
															at0011, 	-- Left
															at0012]	-- Right
														}
													}
												}
											}
											ELEMENT[at0009] occurrences matches {0..1} matches {	-- Rinne Test Result
												value matches {
													DV_CODED_TEXT matches {
														defining_code matches {
															[local::
															at0014, 	-- Positive
															at0013]	-- Negative
														}
													}
												}
											}
										}
									}
									ELEMENT[at0017] occurrences matches {0..*} matches {	-- Clinical Interpretation
										value matches {
											DV_TEXT matches {*}
										}
									}
									ELEMENT[at0018] occurrences matches {0..*} matches {	-- Comment
										value matches {
											DV_TEXT matches {*}
										}
									}
								}
							}
						}
					}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Rinne and Weber Test Results">
					description = <"Two hearing screening tests, commonly recorded together to determine the presence and character of any detected hearing loss.">
				>
				["at0001"] = <
					text = <"Event Series">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Any event">
					description = <"Default, unspecified point in time or interval event which may be explicitly defined in a template or at run-time.">
				>
				["at0003"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0004"] = <
					text = <"Weber Test Result">
					description = <"A test to compare bone conduction in both ears.">
				>
				["at0005"] = <
					text = <"No Lateralisation">
					description = <"The sound from vibration is heard equally in both ears.">
				>
				["at0006"] = <
					text = <"Lateralising Left">
					description = <"The sound from the vibration is heard predominantly on the left.">
				>
				["at0007"] = <
					text = <"Lateralising Right">
					description = <"The sound from the vibration is heard predominantly on the right.">
				>
				["at0008"] = <
					text = <"Rinne Test">
					description = <"A test to compare the subject's perception of sounds transmitted by air conduction to those transmitted by bone conduction through the mastoid.">
				>
				["at0009"] = <
					text = <"Rinne Test Result">
					description = <"The result of the Rinne Test.">
				>
				["at0010"] = <
					text = <"Ear Tested">
					description = <"Identification of the ear being tested.">
				>
				["at0011"] = <
					text = <"Left">
					description = <"The left ear was tested.">
				>
				["at0012"] = <
					text = <"Right">
					description = <"The right ear was tested.">
				>
				["at0013"] = <
					text = <"Negative">
					description = <"Air Conduction is less than bone conduction.">
				>
				["at0014"] = <
					text = <"Positive">
					description = <"Air Conduction is greater than bone conduction.">
				>
				["at0017"] = <
					text = <"Clinical Interpretation">
					description = <"Single word, phrase or brief description represents the clinical meaning and significance of the physical examination findings.">
				>
				["at0018"] = <
					text = <"Comment">
					description = <"Additional narrative about the Rinne and Weber tests not captured in other fields.">
				>
			>
		>
	>