archetype (adl_version=1.4)
	openEHR-EHR-OBSERVATION.substance_use.v1

concept
	[at0000]	-- Substance Use
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"heather.leslie@oceaninformatics.com">
		["date"] = <"6/05/2009">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"This is a generic archetype used to record details of the use of any and all substances. ">
			use = <"This is a generic archetype used to record details of the use of any and all substances that have not had specific specialisation archetypes created.  This includes use at specific point in time, over intervals of time, and use of mathematical functions such as average or minimum eg average consumption over a week.  
A typical use of this archetype will be related to a diary record of use or consumption of substances, especially those with addictive properties.  ">
			keywords = <"substance", "addiction", "consumption", "use">
			misuse = <"Do not use this archetype for recording summary details about the use of the substance - this should be captured using the EVALUATION.substance_use_summary archetype.  
Do not use this archetype for recording use or consumption histories for common substances such as tobacco smoking and alcohol consumption.  As these are so commonly consumed, data should be recorded using detailed and specific specialisations of this archetype.">
			copyright = <"copyright (c) 2009 openEHR Foundation">
		>
	>
	lifecycle_state = <"0">
	other_contributors = <"Sam Heard, Ocean Informatics, Australia", ...>
	other_details = <
		["MD5-CAM-1.0.1"] = <"3C3ACF8C533AAF92BB15F6E60A8E1D9A">
		["references"] = <"">
	>

definition
	OBSERVATION[at0000] matches {	-- Substance Use
		data matches {
			HISTORY[at0001] matches {	-- Event Series
				events cardinality matches {1..*; unordered} matches {
					EVENT[at0002] occurrences matches {0..1} matches {	-- Any event
						data matches {
							ITEM_TREE[at0003] matches {	-- Tree
								items cardinality matches {0..*; unordered} matches {
									ELEMENT[at0004] occurrences matches {0..1} matches {	-- Substance
										value matches {
											DV_TEXT matches {*}
										}
									}
									CLUSTER[at0010] occurrences matches {0..1} matches {	-- Consumption details
										items cardinality matches {0..*; unordered} matches {
											ELEMENT[at0011] occurrences matches {0..1} matches {	-- Form
												value matches {
													DV_TEXT matches {*}
												}
											}
											ELEMENT[at0018] occurrences matches {0..1} matches {	-- Method of use
												value matches {
													DV_TEXT matches {*}
												}
											}
											ELEMENT[at0005] occurrences matches {0..1} matches {	-- Frequency
												value matches {
													DV_CODED_TEXT matches {
														defining_code matches {
															[local::
															at0006, 	-- Daily use
															at0007, 	-- Weekly use
															at0008, 	-- Irregular use
															at0009]	-- No use
														}
													}
												}
											}
											ELEMENT[at0012] occurrences matches {0..*} matches {*}
										}
									}
									ELEMENT[at0013] occurrences matches {0..1} matches {	-- Triggers
										value matches {
											DV_TEXT matches {*}
										}
									}
									allow_archetype CLUSTER[at0014] occurrences matches {0..*} matches {	-- Readiness for change
										include
											archetype_id/value matches {/openEHR-EHR-CLUSTER\.change\.v1/}
									}
									ELEMENT[at0016] occurrences matches {0..1} matches {	-- Evidence of dependence
										value matches {
											DV_TEXT matches {*}
										}
									}
								}
							}
						}
					}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Substance Use">
					description = <"Generic archetype to record the actual use or consumption of a defined substance at the present time, a specific time or over a period of time. ">
				>
				["at0001"] = <
					text = <"Event Series">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Any event">
					description = <"Any event">
				>
				["at0003"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0004"] = <
					text = <"Substance">
					description = <"Identification of substance ">
				>
				["at0005"] = <
					text = <"Frequency">
					description = <"Frequency of use of substance">
				>
				["at0006"] = <
					text = <"Daily use">
					description = <"Used every day">
				>
				["at0007"] = <
					text = <"Weekly use">
					description = <"Used at least weekly">
				>
				["at0008"] = <
					text = <"Irregular use">
					description = <"Used irregularly">
				>
				["at0009"] = <
					text = <"No use">
					description = <"Not used at all">
				>
				["at0010"] = <
					text = <"Consumption details">
					description = <"Details about the consumption of the substance">
				>
				["at0011"] = <
					text = <"Form">
					description = <"Form of the substance used">
				>
				["at0012"] = <
					text = <"Amount">
					description = <"Amount of substance consumed.  Data type can be further specified in specialised archetypes or in templates">
				>
				["at0013"] = <
					text = <"Triggers">
					description = <"Identified triggers which stimulate or cause use">
				>
				["at0014"] = <
					text = <"Readiness for change">
					description = <"Details about the readiness to change use or consumption of substance">
				>
				["at0016"] = <
					text = <"Evidence of dependence">
					description = <"Description of any evidence of dependence on the substance">
				>
				["at0018"] = <
					text = <"Method of use">
					description = <"Method of use or consumption of the substance">
				>
			>
		>
	>