archetype (adl_version=1.4)
	openEHR-EHR-EVALUATION.nutrition_summary.v1

concept
	[at0000]	-- Nutrition Summary
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Hugh Leslie">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"hugh.leslie@oceaninformatics.com">
		["date"] = <"17/12/2010">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record an overview of the nutritional status of an individual.">
			use = <"Use to record an overview of the nutritional status of an individual, as assessed by a clinician.">
			keywords = <"nutrition", "obese", "overweight", "underweight", "malnourished">
			misuse = <"Not to be used to record measurements such as weight, height or Body Mass Index. Use specific archetypes to record these measurements - OBSERVATION.weight, OBSERVATION.height and OBSERVATION.body_mass_index.">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"CommitteeDraft">
	other_contributors = <"Stephen Chu, NEHTA, Australia", ...>
	other_details = <
		["MD5-CAM-1.0.1"] = <"D149F48F406915A685CCB404619E7B42">
	>

definition
	EVALUATION[at0000] matches {	-- Nutrition Summary
		data matches {
			ITEM_TREE[at0001] matches {	-- Tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0002] occurrences matches {0..1} matches {	-- Nutrition status
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0003] occurrences matches {0..1} matches {	-- Weight status
						value matches {
							DV_CODED_TEXT matches {
								defining_code matches {
									[local::
									at0004, 	-- Underweight
									at0007, 	-- Normal
									at0005, 	-- Overweight
									at0006]	-- Obese
								}
							}
						}
					}
					ELEMENT[at0008] occurrences matches {0..1} matches {	-- Dietary preference
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0009] occurrences matches {0..*} matches {	-- Dietary Requirements
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0010] occurrences matches {0..1} matches {	-- Comment
						value matches {
							DV_TEXT matches {*}
						}
					}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Nutrition Summary">
					description = <"Summary of the nutritional status of an individual, as assessed by a clinician.">
				>
				["at0001"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Nutrition status">
					description = <"Description of the individual's nutritional status as assessed by a clinician, for example, malnourished or well nourished.  Coding with a terminology is desirable, where possible.">
				>
				["at0003"] = <
					text = <"Weight status">
					description = <"Assessment of the individual's weight status.">
				>
				["at0004"] = <
					text = <"Underweight">
					description = <"Is underweight for age and sex according to BMI or other measure.">
				>
				["at0005"] = <
					text = <"Overweight">
					description = <"Is overweight for age and sex according to BMI or other measure.">
				>
				["at0006"] = <
					text = <"Obese">
					description = <"Is obese for age and sex according to BMI or other measure.">
				>
				["at0007"] = <
					text = <"Normal">
					description = <"Is normal weight for age and sex according to BMI or other measure.">
				>
				["at0008"] = <
					text = <"Dietary preference">
					description = <"A description of an individual's dietary preference e.g. Vegetarian or Vegan.  Coding with a terminology is desirable, where possible.">
				>
				["at0009"] = <
					text = <"Dietary Requirements">
					description = <"Description of a special dietary requirement e.g. Lactose free or Gluten free.  Coding with a terminology is desirable, where possible.">
				>
				["at0010"] = <
					text = <"Comment">
					description = <"Comment about the individual's nutrition.">
					fsn = <"Nutrition Summary Comment">
				>
			>
		>
	>