archetype (adl_version=1.4)
	openEHR-EHR-COMPOSITION.prescription.v1

concept
	[at0000]	-- Prescription
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Sam Heard">
		["organisation"] = <"NEHTA">
		["email"] = <"sam.heard@oceaninformatics.com">
		["date"] = <"9/11/2010">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"A composition for transfering medication instructions to the dispensing and/or administration provider.">
			use = <"Only required when communicating a medication instruction. Contextural information in the in this composition only relates to this particular collection of medication instructions and not to the current or future medication instructions.">
			keywords = <"medication", "order", "dispense", "authorisation">
			misuse = <"Not for use within health records - use the Medication Instruction to create actual orders.">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"CommitteeDraft">
	other_contributors = <"openEHR archetype on CKM", "Sharmila Biswas, Australia", "Stephen Chu, NEHTA, Australia (Editor)", "David Evans, Queensland Health, Australia", "Sam Heard, Ocean Informatics, Australia (Editor)", "Heather Leslie, Ocean Informatics, Australia (Editor)", "Michael Osborne, Mater Health Services, Australia", "John Taylor, NEHTA, Australia", "NEHTA Therapeutic Good Use Data Group", "Richard Townley-O'Neill, NEHTA, Australia (Editor)">
	other_details = <
		["MD5-CAM-1.0.1"] = <"880F30F8311EC2DFAFD484ABB19F238A">
	>

definition
	COMPOSITION[at0000] matches {	-- Prescription
		category matches {
			DV_CODED_TEXT matches {
				defining_code matches {[openehr::433]}
			}
		}
		context matches {
			EVENT_CONTEXT matches {
				other_context matches {
					ITEM_TREE[at0001] matches {	-- Tree
						items cardinality matches {0..*; unordered} matches {
							CLUSTER[at0002] occurrences matches {0..*} matches {	-- Qualification
								items cardinality matches {1..*; unordered} matches {
									ELEMENT[at0003] occurrences matches {0..1} matches {	-- OrderID
										value matches {
											DV_EHR_URI matches {*}
											DV_IDENTIFIER matches {*}
										}
									}
									ELEMENT[at0004] occurrences matches {0..*} matches {	-- Endorsement
										value matches {
											DV_TEXT matches {*}
										}
									}
									ELEMENT[at0005] occurrences matches {0..*} matches {	-- AuthorisationID
										value matches {
											DV_IDENTIFIER matches {*}
										}
									}
									ELEMENT[at0006] occurrences matches {0..*} matches {	-- Comment
										value matches {
											DV_TEXT matches {*}
										}
									}
								}
							}
						}
					}
				}
			}
		}
		content cardinality matches {1..*; unordered} matches {
			allow_archetype INSTRUCTION[at0007] occurrences matches {1..*} matches {	-- Medication instruction
				include
					archetype_id/value matches {/openEHR-EHR-INSTRUCTION\.medication\.v1/}
			}
			allow_archetype ENTRY[at0008] occurrences matches {0..*} matches {	-- Other data
				include
					archetype_id/value matches {/.*/}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Prescription">
					description = <"A document authorising supply and administration of one or more medicines, vaccines or other therapeutic goods (as a collection of medication instrations) to be communicated to a dispensing or administration provider.">
				>
				["at0001"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Qualification">
					description = <"Qualifications on any medication order included in the prescription.">
				>
				["at0003"] = <
					text = <"OrderID">
					description = <"The path or ID of the order referenced. If there is no OrderID then the endorsement relates to the entire prescription.">
				>
				["at0004"] = <
					text = <"Endorsement">
					description = <"Asserting that a special condition applies such as approval for  enhanced subsidy or concurrent supply. Australian examples include Regulation 24 (PBS), Hardship Conditions (RPBS) or CTG for 'close the gap'.">
				>
				["at0005"] = <
					text = <"AuthorisationID">
					description = <"An identifier authorising prescription, dispensing or reimbursement for this medication order.">
				>
				["at0006"] = <
					text = <"Comment">
					description = <"Comment on any qualification.">
				>
				["at0007"] = <
					text = <"Medication instruction">
					description = <"Contains one or more medication instructions to be supplied.">
				>
				["at0008"] = <
					text = <"Other data">
					description = <"Other observational or relevant data.">
				>
			>
		>
	>