archetype (adl_version=1.4)
	openEHR-EHR-CLUSTER.skin.v1

concept
	[at0000]	-- Skin
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Ocean Informatics">
		["email"] = <"heather.leslie@oceaninformatics.com">
		["date"] = <"2012-11-01">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"For recording the examination findings from the physical examination of an explicitly identified area of skin.">
			use = <"Use to record the examination findings from the physical examination of an explicitly identified area of skin. 

This archetype is designed to be used in SLOTs within clinically appropriate OBSERVATION or other CLUSTER archetypes as part of recording the findings on clinical examination - for example nested within OBSERVATION.exam or CLUSTER.pinna_mastoid.

Inspection of the skin is assumed to be done using direct visualisation. If a device is used, it should be recorded as part of the method of examination in the ENTRY archetype - for example, the OBSERVATION.exam family of archetypes.">
			misuse = <"">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"CommitteeDraft">
	other_contributors = <"Kerrie Lee", ...>
	other_details = <
		["current_contact"] = <"Heather Leslie, Ocean Informatics, heather.leslie@oceaninformatics.com">
		["references"] = <"Direct communications with clinical domain experts.">
		["MD5-CAM-1.0.1"] = <"B01EE71FA3E00BFDA06A04F994729EA9">
	>

definition
	CLUSTER[at0000] matches {	-- Skin
		items cardinality matches {1..*; unordered} matches {
			ELEMENT[at0003] matches {	-- Anatomical Location
				value matches {
					DV_TEXT matches {*}
				}
			}
			ELEMENT[at0001] occurrences matches {0..1} matches {	-- Clinical Description
				value matches {
					DV_TEXT matches {*}
				}
			}
			ELEMENT[at0004] occurrences matches {0..1} matches {	-- Erythema
				value matches {
					DV_TEXT matches {*}
				}
			}
			ELEMENT[at0005] occurrences matches {0..1} matches {	-- Swelling
				value matches {
					DV_TEXT matches {*}
				}
			}
			ELEMENT[at0007] occurrences matches {0..1} matches {	-- Tenderness
				value matches {
					DV_TEXT matches {*}
				}
			}
			allow_archetype CLUSTER[at0006] occurrences matches {0..*} matches {	-- Details
				include
					archetype_id/value matches {/openEHR-EHR-CLUSTER\.scar(-[a-zA-Z0-9_]+)*\.v1|openEHR-EHR-CLUSTER\.device(-[a-zA-Z0-9_]+)*\.v1/}
			}
			ELEMENT[at0002] occurrences matches {0..*} matches {	-- Clinical Interpretation
				value matches {
					DV_TEXT matches {*}
				}
			}
			ELEMENT[at0009] occurrences matches {0..1} matches {	-- Multimedia Representation
				value matches {
					DV_MULTIMEDIA matches {
						media_type matches {
							[openEHR::
							401, 
							402, 
							404, 
							405, 
							406, 
							407, 
							414, 
							425, 
							426, 
							427, 
							428, 
							429]
						}
					}
				}
			}
			ELEMENT[at0008] occurrences matches {0..1} matches {	-- Comment
				value matches {
					DV_TEXT matches {*}
				}
			}
		}
	}

ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Skin">
					description = <"Physical examination of an explicitly identified area of skin.">
				>
				["at0001"] = <
					text = <"Clinical Description">
					description = <"Narrative description of the skin of the skin.">
					comment = <"For example, thickness/atrophy, or presence of pigmentation.">
				>
				["at0002"] = <
					text = <"Clinical Interpretation">
					description = <"Single word, phrase or brief description representing a summary of the findings of the region of skin being examined.">
					comment = <"For example, infected IV site or eczema.">
				>
				["at0003"] = <
					text = <"Anatomical Location">
					description = <"Identification of the anatomical location of the skin being examined.">
					comment = <"Coding with a terminology is desirable, where possible. For example, a broad region such as the left arm; or a smaller, specific area such as the right eyelid. If this archetype is already nested within an archetype where the appropriate level of detail for identification of the anatomical location has already been specified, this data element may be regarded as redundant, or the system may automatically insert the same anatomical location here.">
				>
				["at0004"] = <
					text = <"Erythema">
					description = <"Narrative description of any observed erythema or redness in the skin.">
				>
				["at0005"] = <
					text = <"Swelling">
					description = <"Narrative description of any observed swelling in the skin.">
				>
				["at0006"] = <
					text = <"Details">
					description = <"Detailed structured examination findings.">
					comment = <"For example, further details about a scar or an identified lesion, or an intravenous catheter that is inserted in the area.">
				>
				["at0007"] = <
					text = <"Tenderness">
					description = <"Narrative description of any tenderness noted on palpation of the skin.">
				>
				["at0008"] = <
					text = <"Comment">
					description = <"Additional narrative comment about the examination, not captured in other structured data fields.">
				>
				["at0009"] = <
					text = <"Multimedia Representation">
					description = <"Digital image, video or diagram of the skin.">
				>
			>
		>
	>